DFRobot LCDshield example port

LeafLabs Garden » Support » Maple Hardware Support

DFRobot LCDshield example port

(12 posts) (7 voices)

Started 4 years ago by supermac
Latest reply from InsanityIdeas

supermac
Member

This is a port for the DFRobot LCD Shield example with the five buttons. This code uses the LCD to test the buttons and is a great place to start for your simple device. ADC values and pins are correct for the Maple.
Tested on the maple and the olimexino STM.

#include <LiquidCrystal.h>

#include "libmaple.h"

//Key message
char msgs[5][15] = {"Right Key OK ",
"Up Key OK ",
"Down Key OK ",
"Left Key OK ",
"Select Key OK" };
int adc_key_val[5] ={30*4, 150*4, 360*4, 535*4, 760*4 };
int NUM_KEYS = 5;
int adc_key_in;
int keypadPin = 15;//adc pin input for key function
int key=-1;
int oldkey=-1;
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);

void setup() {
pinMode(13, OUTPUT); //we'll use the debug LED to output a heartbeat

//lcd.init();
//optionally, now set up our application-specific display settings, overriding whatever the lcd did in lcd.init()
//lcd.commandWrite(0x0F);//cursor on, display on, blink on. (nasty!)
lcd.clear();
lcd.print("KEYPAD testing... pressing");

}

void loop() {

adc_key_in = analogRead(keypadPin); // read the value from the sensor
digitalWrite(13, HIGH);
key = get_key(adc_key_in); // convert into key press

if (key != oldkey) // if keypress is detected
{
delay(50); // wait for debounce time
adc_key_in = analogRead(keypadPin); // read the value from the sensor
key = get_key(adc_key_in); // convert into key press
if (key != oldkey)
{
oldkey = key;
if (key >=0)
{
lcd.clear();
lcd.setCursor(2, 0); //line=2, x=0
lcd.print(msgs[key]);
}
}
}

//delay(1000);
digitalWrite(13, LOW);

}

// Convert ADC value to key number
int get_key(int input)
{
int k;

for (k = 0; k < NUM_KEYS; k++)
{
if (input < adc_key_val[k])
{

return k;
}
}

if (k >= NUM_KEYS)
k = -1; // No valid key pressed

return k;
}

Posted 4 years ago #
mbolivar
LeafLabs

Hi supermac,

Thanks for posting! This seems like a good addition for the Compatible Shields page in our wiki; would you please add it?

Posted 4 years ago #
Cyclegadget
Member

I have the DFRobot LCD Shield. Thanks for posting.

However, the only problem is I am only able to use one line of the display. Such as lcd.setCursor(2, 0);

If I want to use the next line lcd.setCursor(2, 1);...the text does not appear on the screen.

I think the problem is in this area:
//lcd.init();
//optionally, now set up our application-specific display settings, overriding whatever the lcd did in lcd.init()

Can anyone help?

Thanks,
Mark

Posted 3 years ago #

Cyclegadget
Member

This code will only use the first line of the LCD. It will not work at all unless I comment out this lcd.begin(16, 2);

Any suggestions are welcome.

#include <LiquidCrystal.h>
#include <LCDKeypad.h>
#include "libmaple.h"

#define MINVAL 1
#define MAXVAL 1000

LCDKeypad lcd;

byte c_up[8] = {
  B00100,
  B01110,
  B10101,
  B00100,
  B00100,
  B00100,
  B00100,
  B00100,
};

byte c_down[8] = {
  B00100,
  B00100,
  B00100,
  B00100,
  B00100,
  B10101,
  B01110,
  B00100,
};

byte c_select[8] = {
  B00000,
  B01110,
  B11111,
  B11111,
  B11111,
  B11111,
  B01110,
  B00000,
};

void setup()
{
  int i,k;

  lcd.createChar(1,c_select);
  lcd.createChar(2,c_up);
  lcd.createChar(3,c_down);
 // lcd.begin(16, 2);
  lcd.clear();
  lcd.print("     Guess");
  lcd.setCursor(0,1);
  lcd.print("   The Number");
  delay(3000);
  for (k=0;k<3;k++)
  {
    lcd.scrollDisplayLeft();
    delay(200);
  }
  for (i=0;i<3;i++)
  {
    for (k=0;k<6;k++)
    {
      lcd.scrollDisplayRight();
      delay(200);
    }
    for (k=0;k<6;k++)
    {
      lcd.scrollDisplayLeft();
      delay(200);
    }
  }
  for (k=0;k<16;k++)
  {
    lcd.scrollDisplayLeft();
    delay(200);
  }
}

void loop()
{
  int bottom=MINVAL, top=MAXVAL;
  int trynumber=0;
  int guess, buttonPressed;

  lcd.clear();
  lcd.print("Make up a number");
  lcd.setCursor(0,1);
  lcd.print("from ");
  lcd.print(MINVAL,DEC);
  lcd.print(" to ");
  lcd.print(MAXVAL,DEC);
  lcd.print(" ");
  waitButton();
  waitReleaseButton();
  do
  {
    lcd.clear();
    guess=bottom+(top-bottom)/2;
    trynumber++;

    lcd.print("Is it ");
    lcd.print(guess,DEC);
    lcd.print("?");
    lcd.setCursor(0,1);
    lcd.write(1);
    lcd.write(' ');
    lcd.write(2);
    lcd.write(' ');
    lcd.write(3);
    lcd.write(' ');
    do
    {
      buttonPressed=waitButton();
    }
    while(!(buttonPressed==KEYPAD_SELECT || buttonPressed==KEYPAD_UP || buttonPressed==KEYPAD_DOWN));
    lcd.setCursor(0,1);
    lcd.write(buttonPressed==KEYPAD_SELECT?1:' ');
    lcd.write(' ');
    lcd.write(buttonPressed==KEYPAD_UP?2:' ');
    lcd.write(' ');
    lcd.write(buttonPressed==KEYPAD_DOWN?3:' ');
    delay(100);
    waitReleaseButton();
    if (buttonPressed==KEYPAD_UP)
    {
      bottom=constrain(guess+1,MINVAL,top);
    }
    else if (buttonPressed==KEYPAD_DOWN)
    {
      top=constrain(guess-1,bottom,MAXVAL);
    }
  }
  while (buttonPressed!=KEYPAD_SELECT && top!=bottom);
  lcd.clear();
  if (top==bottom)
  {
    lcd.print("It must be ");
    guess=top;
  }
  else
  {
    lcd.print("It is ");
  }
  lcd.print(guess,DEC);
  lcd.print("!");
  lcd.setCursor(0,1);
  lcd.print("Tries: ");
  lcd.print(trynumber,DEC);
  lcd.print(" ");
  waitButton();
  waitReleaseButton();
}

int waitButton()
{
  int buttonPressed;
  waitReleaseButton;
  lcd.blink();
  while((buttonPressed=lcd.button())==KEYPAD_NONE)
  {
  }
  delay(50);
  lcd.noBlink();
  return buttonPressed;
}

void waitReleaseButton()
{
  delay(50);
  while(lcd.button()!=KEYPAD_NONE)
  {
  }
  delay(50);
}

Posted 3 years ago #

Cyclegadget
Member

I have solved my issues with the DFRobot LCD Shield and perhaps other LCD devices using the 4bit Mod!

To make a long story short, the library did not allow enough delay between commands when initializing the LCD. I added more delay time to the library .cpp and now I can set the cursor with no problems!

I found documentation related to LCD's and LCD Initialization.
Here is the link: http://web.alfredstate.edu/weimandn/lcd/lcd_initialization/lcd_initialization_index.html

Posted 3 years ago #

Cyclegadget
Member

The changes are in the area of line 109 to 147. Here is my modified library code:

#include "LiquidCrystal.h"

#include <stdio.h>
#include <string.h>
#include "WProgram.h"

// When the display powers up, it is configured as follows:
//
// 1. Display clear
// 2. Function set:
//    DL = 1; 8-bit interface data
//    N = 0; 1-line display
//    F = 0; 5x8 dot character font
// 3. Display on/off control:
//    D = 0; Display off
//    C = 0; Cursor off
//    B = 0; Blinking off
// 4. Entry mode set:
//    I/D = 1; Increment by 1
//    S = 0; No shift
//
// Note, however, that resetting the Arduino doesn't reset the LCD, so we
// can't assume that its in that state when a sketch starts (and the
// LiquidCrystal constructor is called).

// This library has been modified to be compatible with the LeafLabs Maple;
// very conservative timing is used due to problems with delayMicroseconds()
// that should be fixed in the 0.0.7 release of the libmaple. [bnewbold]

LiquidCrystal::LiquidCrystal(uint8 rs, uint8 rw, uint8 enable,
                             uint8 d0, uint8 d1, uint8 d2, uint8 d3,
                             uint8 d4, uint8 d5, uint8 d6, uint8 d7)
{
  init(0, rs, rw, enable, d0, d1, d2, d3, d4, d5, d6, d7);
}

LiquidCrystal::LiquidCrystal(uint8 rs, uint8 enable,
                             uint8 d0, uint8 d1, uint8 d2, uint8 d3,
                             uint8 d4, uint8 d5, uint8 d6, uint8 d7)
{
  init(0, rs, 255, enable, d0, d1, d2, d3, d4, d5, d6, d7);
}

LiquidCrystal::LiquidCrystal(uint8 rs, uint8 rw, uint8 enable,
                             uint8 d0, uint8 d1, uint8 d2, uint8 d3)
{
  init(1, rs, rw, enable, d0, d1, d2, d3, 0, 0, 0, 0);
}

LiquidCrystal::LiquidCrystal(uint8 rs,  uint8 enable,
                             uint8 d0, uint8 d1, uint8 d2, uint8 d3)
{
  init(1, rs, 255, enable, d0, d1, d2, d3, 0, 0, 0, 0);
}

void LiquidCrystal::init(uint8 fourbitmode, uint8 rs, uint8 rw, uint8 enable,
                         uint8 d0, uint8 d1, uint8 d2, uint8 d3,
                         uint8 d4, uint8 d5, uint8 d6, uint8 d7)
{
  _rs_pin = rs;
  _rw_pin = rw;
  _enable_pin = enable;

  _data_pins[0] = d0;
  _data_pins[1] = d1;
  _data_pins[2] = d2;
  _data_pins[3] = d3;
  _data_pins[4] = d4;
  _data_pins[5] = d5;
  _data_pins[6] = d6;
  _data_pins[7] = d7;

  for (int i = 0; i < 8 - fourbitmode * 4; i++) {
      pinMode(_data_pins[i], OUTPUT);
  }

  pinMode(_rs_pin, OUTPUT);
  // we can save 1 pin by not using RW. Indicate by passing 255 instead of pin#
  if (_rw_pin != 255) {
    pinMode(_rw_pin, OUTPUT);
  }
  pinMode(_enable_pin, OUTPUT);

  if (fourbitmode)
    _displayfunction = LCD_4BITMODE | LCD_1LINE | LCD_5x8DOTS;
  else
    _displayfunction = LCD_8BITMODE | LCD_1LINE | LCD_5x8DOTS;

  // TODO: bnewbold, re-enable this?
  begin(16, 1);
}

void LiquidCrystal::begin(uint8 cols, uint8 lines, uint8 dotsize) {
  if (lines > 1) {
    _displayfunction |= LCD_2LINE;
  }
  _numlines = lines;
  _currline = 0;

  // for some 1 line displays you can select a 10 pixel high font
  if ((dotsize != 0) && (lines == 1)) {
    _displayfunction |= LCD_5x10DOTS;
  }

  // SEE PAGE 45/46 FOR INITIALIZATION SPECIFICATION!  according to
  // datasheet, we need at least 40ms after power rises above 2.7V
  // before sending commands. Arduino can turn on way befer 4.5V so
  // we'll wait 50
  delay(100);    // Maple mod
  //delayMicroseconds(50000);
  // Now we pull both RS and R/W low to begin commands
  digitalWrite(_rs_pin, LOW);
  digitalWrite(_enable_pin, LOW);
  if (_rw_pin != 255) {
    digitalWrite(_rw_pin, LOW);
  }

  //put the LCD into 4 bit or 8 bit mode
  if (! (_displayfunction & LCD_8BITMODE)) {
    // this is according to the hitachi HD44780 datasheet
    // figure 24, pg 46

    // we start in 8bit mode, try to set 4 bit mode
    write4bits(0x03);
    delay(50);   // Maple mod
    //delayMicroseconds(4500); // wait min 4.1ms

    // second try
    write4bits(0x03);
    delay(50);   // Maple mod
    //delayMicroseconds(4500); // wait min 4.1ms

    // third go!
    write4bits(0x03);
    delay(10);   // Maple mod
    //delayMicroseconds(150);

    // finally, set to 8-bit interface
    write4bits(0x02);
  } else {
    // this is according to the hitachi HD44780 datasheet
    // page 45 figure 23

    // Send function set command sequence
    command(LCD_FUNCTIONSET | _displayfunction);
    delay(50);   // Maple mod
    //delayMicroseconds(4500);  // wait more than 4.1ms

    // second try
    command(LCD_FUNCTIONSET | _displayfunction);
    delay(1);   // Maple mod
    //delayMicroseconds(150);

    // third go
    command(LCD_FUNCTIONSET | _displayfunction);
  }

  // finally, set # lines, font size, etc.
  command(LCD_FUNCTIONSET | _displayfunction);

  // turn the display on with no cursor or blinking default
  _displaycontrol = LCD_DISPLAYON | LCD_CURSOROFF | LCD_BLINKOFF;
  display();

  // clear it off
  clear();

  // Initialize to default text direction (for romance languages)
  _displaymode = LCD_ENTRYLEFT | LCD_ENTRYSHIFTDECREMENT;
  // set the entry mode
  command(LCD_ENTRYMODESET | _displaymode);

}

/********** high level commands, for the user! */
void LiquidCrystal::clear()
{
  command(LCD_CLEARDISPLAY);  // clear display, set cursor position to zero
  delay(20);     // Maple mod
  //delayMicroseconds(2000);  // this command takes a long time!
}

void LiquidCrystal::home()
{
  command(LCD_RETURNHOME);  // set cursor position to zero
  delay(2);     // Maple mod
  //delayMicroseconds(2000);  // this command takes a long time!
}

void LiquidCrystal::setCursor(uint8 col, uint8 row)
{
  int row_offsets[] = { 0x00, 0x40, 0x14, 0x54 };
  if ( row > _numlines ) {
    row = _numlines-1;    // we count rows starting w/0
  }

  command(LCD_SETDDRAMADDR | (col + row_offsets[row]));
}

// Turn the display on/off (quickly)
void LiquidCrystal::noDisplay() {
  _displaycontrol &= ~LCD_DISPLAYON;
  command(LCD_DISPLAYCONTROL | _displaycontrol);
}
void LiquidCrystal::display() {
  _displaycontrol |= LCD_DISPLAYON;
  command(LCD_DISPLAYCONTROL | _displaycontrol);
}

// Turns the underline cursor on/off
void LiquidCrystal::noCursor() {
  _displaycontrol &= ~LCD_CURSORON;
  command(LCD_DISPLAYCONTROL | _displaycontrol);
}
void LiquidCrystal::cursor() {
  _displaycontrol |= LCD_CURSORON;
  command(LCD_DISPLAYCONTROL | _displaycontrol);
}

// Turn on and off the blinking cursor
void LiquidCrystal::noBlink() {
  _displaycontrol &= ~LCD_BLINKON;
  command(LCD_DISPLAYCONTROL | _displaycontrol);
}
void LiquidCrystal::blink() {
  _displaycontrol |= LCD_BLINKON;
  command(LCD_DISPLAYCONTROL | _displaycontrol);
}

// These commands scroll the display without changing the RAM
void LiquidCrystal::scrollDisplayLeft(void) {
  command(LCD_CURSORSHIFT | LCD_DISPLAYMOVE | LCD_MOVELEFT);
}
void LiquidCrystal::scrollDisplayRight(void) {
  command(LCD_CURSORSHIFT | LCD_DISPLAYMOVE | LCD_MOVERIGHT);
}

// This is for text that flows Left to Right
void LiquidCrystal::leftToRight(void) {
  _displaymode |= LCD_ENTRYLEFT;
  command(LCD_ENTRYMODESET | _displaymode);
}

// This is for text that flows Right to Left
void LiquidCrystal::rightToLeft(void) {
  _displaymode &= ~LCD_ENTRYLEFT;
  command(LCD_ENTRYMODESET | _displaymode);
}

// This will 'right justify' text from the cursor
void LiquidCrystal::autoscroll(void) {
  _displaymode |= LCD_ENTRYSHIFTINCREMENT;
  command(LCD_ENTRYMODESET | _displaymode);
}

// This will 'left justify' text from the cursor
void LiquidCrystal::noAutoscroll(void) {
  _displaymode &= ~LCD_ENTRYSHIFTINCREMENT;
  command(LCD_ENTRYMODESET | _displaymode);
}

// Allows us to fill the first 8 CGRAM locations
// with custom characters
void LiquidCrystal::createChar(uint8 location, uint8 charmap[]) {
  location &= 0x7; // we only have 8 locations 0-7
  command(LCD_SETCGRAMADDR | (location << 3));
  for (int i=0; i<8; i++) {
    write(charmap[i]);
  }
}

/*********** mid level commands, for sending data/cmds */

inline void LiquidCrystal::command(uint8 value) {
  send(value, LOW);
}

inline void LiquidCrystal::write(uint8 value) {
  send(value, HIGH);
}

/************ low level data pushing commands **********/

// write either command or data, with automatic 4/8-bit selection
void LiquidCrystal::send(uint8 value, uint8 mode) {
  digitalWrite(_rs_pin, mode);

  // if there is a RW pin indicated, set it low to Write
  if (_rw_pin != 255) {
    digitalWrite(_rw_pin, LOW);
  }

  if (_displayfunction & LCD_8BITMODE) {
    write8bits(value);
  } else {
    write4bits(value>>4);
    write4bits(value);
  }
}

void LiquidCrystal::pulseEnable(void) {
  // _enable_pin should already be LOW (unless someone else messed
  // with it), so don't sit around waiting for long.
  digitalWrite(_enable_pin, LOW);
  delayMicroseconds(1);

  // Enable pulse must be > 450 ns.  Value chosen here according to
  // the following threads:
  // http://forums.leaflabs.com/topic.php?id=640
  // http://forums.leaflabs.com/topic.php?id=512
  togglePin(_enable_pin);
  delayMicroseconds(1);
  togglePin(_enable_pin);

  // Commands needs > 37us to settle.
  delayMicroseconds(42);
}

void LiquidCrystal::write4bits(uint8 value) {
  for (int i = 0; i < 4; i++) {
    digitalWrite(_data_pins[i], (value >> i) & 0x01);
  }

  pulseEnable();
}

void LiquidCrystal::write8bits(uint8 value) {
  for (int i = 0; i < 8; i++) {
    digitalWrite(_data_pins[i], (value >> i) & 0x01);
  }

  pulseEnable();
}

Posted 3 years ago #

Cyclegadget
Member

Here is a working test sketch that shows the cursor position working on both lines:

#include <LiquidCrystal.h>

#include "libmaple.h"

int lastDebounceTime = 0;   // the last time the output pin was toggled
int debounceDelay = 80;     // the debounce time; increase if the output flickers

//Key message
char msgs[5][15] = {
  "Right Key  ",
  "Up Key ",
  "Down Key ",
  "Left Key  ",
  "Select Key " };
int adc_key_val[5] ={
  30*4, 195*4, 368*4, 545*4, 780*4 };
int NUM_KEYS = 5;
int adc_key_in;
int keypadPin = 15;//adc pin input for key function
int key=-1;
int oldkey=-1;
const int numRows = 2;
const int numCols = 16;
LiquidCrystal lcd(8, 9, 4, 5, 6, 7);

void setup() {
  // set up the LCD's number of columns and rows
  lcd.begin(numCols,numRows);
  lcd.clear();
  lcd.print("KEYPAD testing.");
  delay(2000);
 lcd.setCursor(0, 1);   //(thisRow,thisCol)
 lcd.print("Working???");
 delay(2000);
 lcd.clear();
  lcd.setCursor(1,0);   //(thisRow,thisCol)
  lcd.print("Yes it is good");
  delay(2000);
  lcd.setCursor(0, 1);   //(thisRow,thisCol)
 lcd.print("Wonderful!!!");

}

void loop() {

  adc_key_in = analogRead(keypadPin); // read the value from the sensor
  SerialUSB.println( adc_key_in);

  key = get_key(adc_key_in); // convert into key press

  if (key != oldkey) // if keypress is detected
  {
    oldkey = key;
    lastDebounceTime = millis();
  }
  if ((millis() - lastDebounceTime) > debounceDelay) {
    adc_key_in = analogRead(keypadPin); // read the value from the sensor
    key = get_key(adc_key_in); // convert into key press
    if (key == oldkey)
    {

      if (key >=0)
      {
        key = get_key(adc_key_in); // convert into key press
        lcd.clear();
        lcd.setCursor(2, 0); //line=2, x=0
        lcd.print(msgs[key]);
      }
    }

  }
}

// Convert ADC value to key number
int get_key(int input)
{
  int k;

  for (k = 0; k < NUM_KEYS; k++)
  {
    if (input < adc_key_val[k])
    {

      return k;
    }
  }

  if (k >= NUM_KEYS)
    k = -1; // No valid key pressed

  return k;
}

Posted 3 years ago #

gbulmer
Moderator

Cyclegadget - I added backquote characters around your code so that layout is preserved.
LeafLabs ask that folks to use pastebin for code so that posts are a bit shorter.

(Full disclosure: I am not a member of LeafLabs staff)

Posted 3 years ago #
stumo
Member

I have the DFRobot LCD and Olimexino STM32, but the display contrast is very dim, so much so that it is very hard to read. The pot on the board doesn't help. I guess its a 5V LCD board being driven at 3V3 by the Olimexino.

So is there some way I can make the contrast better?

Posted 3 years ago #
Cyclegadget
Member

Sorry for the late reply. I agree the lcd is a bit dim and I think it is because of the STM board being 3v3 instead of 5v.

The only advice I can give is that when I use lcd.clear() too frequently, it make the lcd even dimmer.

I don't know if there is anything else you can do to help contrast. (

Posted 3 years ago #
higwoshy
Member

Hi, re : dim LCD

I don't know if this will help, but I was playing around with a 20x4 white/blue LCD just yesterday and I had a problem with it not showing much when powered by 3.3V. From 5V it was perfect.

Have you tried a charge pump circuit to get the voltage upto +5V? It consists of a couple of caps and diodes, the input being a PWM output from the Maple. It's very simple and works surprisingly well. The output is close to +6V, though it's not a perfect output. It does use one more maple pin, but I just plugged into the nearest PWM output that I was using already and this was good enough.

Lookup "Voltage Generating Circuits for LCD Contrast Control" on search engines should point to an informative pdf. I didn't need the 10k pot.

Posted 3 years ago #
InsanityIdeas
Member

I found my DF Robot LCD Shield to be a bit flaky (as others have mentioned) when using it with Olimexino STM32. I think its because it expects 5 volt inputs, I just get corrupted display suggesting that the data bus isn't being driven well enough. People have suggested work-arounds, but I dont' think the shield should be listed on WIKI as compatible, because out of the box it doesn't work. It works fine with a regular Arduino. Do DF Robot do a 3.3v capable version?

Posted 3 years ago #

RSS feed for this topic

Reply

You must log in to post.