LuisXXVII - The following code works for me. Mainly I changed int to int16, after including stdint.h. Note I'm using pins 9 and 5 on wire.begin. The Adafruit code that consists mainly of cpp library code also works once I adapted it to the Maple wire standard and changed Serial to SerialUSB etc. If you want a copy of that, drop me an email (PeterRArcher@hotrmail.com). By having both versions I can say with confidence they both produce the same data.
/* BMP085 Extended Example Code
by: Jim Lindblom
SparkFun Electronics
date: 1/18/11
license: CC BY-SA v3.0 - http://creativecommons.org/licenses/by-sa/3.0/
Get pressure and temperature from the BMP085 and calculate altitude.
SerialUSB.print it out at 9600 baud to SerialUSB monitor.
Update (7/19/11): I've heard folks may be encountering issues
with this code, who're running an Arduino at 8MHz. If you're
using an Arduino Pro 3.3V/8MHz, or the like, you may need to
increase some of the delays in the bmp085ReadUP and
bmp085ReadUT functions.
*/
#include <Wire.h>
#include <stdint.h>
#define BMP085_ADDRESS 0x77 // I2C address of BMP085
const unsigned char OSS = 0; // Oversampling Setting
// Calibration values
int16 ac1;
int16 ac2;
int16 ac3;
uint16 ac4;
uint16 ac5;
uint16 ac6;
int16 b1;
int16 b2;
int16 mb;
int16 mc;
int16 md;
// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5;
short temperature;
long pressure;
void setup()
{
// SerialUSB.begin(9600);
Wire.begin(9,5);
bmp085Calibration();
}
void loop()
{
temperature = bmp085GetTemperature(bmp085ReadUT());
pressure = bmp085GetPressure(bmp085ReadUP());
SerialUSB.print("Temperature: ");
SerialUSB.print(temperature, DEC);
SerialUSB.println(" *0.1 deg C");
SerialUSB.print("Pressure: ");
SerialUSB.print(pressure, DEC);
SerialUSB.println(" Pa");
SerialUSB.println();
delay(1000);
}
// Stores all of the bmp085's calibration values int16o global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
ac1 = bmp085Readint(0xAA);
ac2 = bmp085Readint(0xAC);
ac3 = bmp085Readint(0xAE);
ac4 = bmp085Readint(0xB0);
ac5 = bmp085Readint(0xB2);
ac6 = bmp085Readint(0xB4);
b1 = bmp085Readint(0xB6);
b2 = bmp085Readint(0xB8);
mb = bmp085Readint(0xBA);
mc = bmp085Readint(0xBC);
md = bmp085Readint(0xBE);
}
// Calculate temperature given ut.
// Value returned will be in units of 0.1 deg C
short bmp085GetTemperature(uint16 ut)
{
long x1, x2;
x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
x2 = ((long)mc << 11)/(x1 + md);
b5 = x1 + x2;
return ((b5 + 8)>>4);
}
// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up)
{
long x1, x2, x3, b3, b6, p;
unsigned long b4, b7;
b6 = b5 - 4000;
// Calculate B3
x1 = (b2 * (b6 * b6)>>12)>>11;
x2 = (ac2 * b6)>>11;
x3 = x1 + x2;
b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;
// Calculate B4
x1 = (ac3 * b6)>>13;
x2 = (b1 * ((b6 * b6)>>12))>>16;
x3 = ((x1 + x2) + 2)>>2;
b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;
b7 = ((unsigned long)(up - b3) * (50000>>OSS));
if (b7 < 0x80000000)
p = (b7<<1)/b4;
else
p = (b7/b4)<<1;
x1 = (p>>8) * (p>>8);
x1 = (x1 * 3038)>>16;
x2 = (-7357 * p)>>16;
p += (x1 + x2 + 3791)>>4;
return p;
}
// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
unsigned char data;
Wire.beginTransmission(BMP085_ADDRESS);
Wire.send(address);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 1);
while(!Wire.available())
;
return Wire.receive();
}
// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int16 bmp085Readint(unsigned char address)
{
unsigned char msb, lsb;
Wire.beginTransmission(BMP085_ADDRESS);
Wire.send(address);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 2);
while(Wire.available()<2)
;
msb = Wire.receive();
lsb = Wire.receive();
return (int16) msb<<8 | lsb;
}
// Read the uncompensated temperature value
uint16 bmp085ReadUT()
{
uint16 ut;
// Write 0x2E int16o Register 0xF4
// This requests a temperature reading
Wire.beginTransmission(BMP085_ADDRESS);
Wire.send(0xF4);
Wire.send(0x2E);
Wire.endTransmission();
// Wait at least 4.5ms
delay(5);
// Read two bytes from registers 0xF6 and 0xF7
ut = bmp085Readint(0xF6);
return ut;
}
// Read the uncompensated pressure value
unsigned long bmp085ReadUP()
{
unsigned char msb, lsb, xlsb;
unsigned long up = 0;
// Write 0x34+(OSS<<6) int16o register 0xF4
// Request a pressure reading w/ oversampling setting
Wire.beginTransmission(BMP085_ADDRESS);
Wire.send(0xF4);
Wire.send(0x34 + (OSS<<6));
Wire.endTransmission();
// Wait for conversion, delay time dependent on OSS
delay(2 + (3<<OSS));
// Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
Wire.beginTransmission(BMP085_ADDRESS);
Wire.send(0xF6);
Wire.endTransmission();
Wire.requestFrom(BMP085_ADDRESS, 3);
// Wait for data to become available
while(Wire.available() < 3)
;
msb = Wire.receive();
lsb = Wire.receive();
xlsb = Wire.receive();
up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);
return up;
}
